Měření vzdálenosti světlem: laserový dálkoměr GY-53 VL53L0X

V jednom z předchozích článků jsme se podívali na ultrazvukový dálkoměr HC-SR04, který měří vzdálenost pomocí zvuku. Tentokrát se podíváme na trochu jiný princip.

V tomto článku si ukážeme modul GY-53 VL53L0X, který měří vzdálenost pomocí infračerveného světla. Často se označuje jako laserový senzor vzdálenosti, ale není to laserové ukazovátko s viditelnou červenou tečkou. Uvnitř je senzor VL53L0X, který pracuje metodou Time-of-Flight, tedy měřením doby letu světla.

Na první pohled jde o malý modul, ale pro pokusy s Arduinem je docela zajímavý. Umí měřit vzdálenost až zhruba do dvou metrů a výsledek dokáže posílat několika způsoby. Konkrétně modul GY-53 nabízí sériový výstup UART, PWM výstup a možnost režimu I2C.

Co je GY-53 VL53L0X

GY-53 je malý modul pro měření vzdálenosti. Hlavní součástkou je čip VL53L0X od STMicroelectronics. Ten v sobě obsahuje infračervený laserový vysílač, přijímací část a elektroniku pro zpracování měření. ST u čipu VL53L0X uvádí neviditelný 940nm VCSEL laser, měření absolutní vzdálenosti až do 2 m a laserovou bezpečnost Class 1.

Zajímavé je, že modul GY-53 není jen obyčejná destička s čipem VL53L0X. Na modulu je navíc malý mikrokontrolér, který měření zpracovává a posílá už hotovou hodnotu vzdálenosti. Díky tomu se dá modul používat i bez složité knihovny. GY-53 umí výstup přes UART + PWM, případně lze přepnout do režimu, kdy se pracuje přímo s čipem přes I2C.

To je výhoda nejen pro začátečníky. Nejjednodušší je začít PWM výstupem, protože k tomu prakticky není potřeba žádná knihovna. Arduino jen změří délku pulzu a z ní vypočítá vzdálenost.

Jak funguje Time-of-Flight

Název Time-of-Flight znamená doslova „doba letu“. Senzor vyšle krátký infračervený světelný impuls směrem k překážce. Světlo se od překážky odrazí a část se vrátí zpět do senzoru. Senzor potom vyhodnotí, za jak dlouho se odražené světlo vrátilo.

Protože světlo letí velmi rychle, není takové měření úplně jednoduché. Uvnitř senzoru je ale elektronika, která se o to postará. Výsledkem je hodnota vzdálenosti v milimetrech.

Zjednodušeně řečeno:

  • senzor vyšle infračervené světlo
  • světlo se odrazí od překážky
  • senzor zachytí odraz
  • elektronika spočítá vzdálenost

Na rozdíl od ultrazvukového senzoru se tedy neměří návrat zvukové vlny, ale návrat světla.

Vývody modulu

Modul má více vývodů, protože podporuje různé způsoby komunikace. Pro základní použití nás budou zajímat hlavně tyto:

VývodVýznam
VCCnapájení modulu
GNDzem
PWMvýstup PWM signálu se vzdáleností
TXsériový výstup z modulu
RXsériový vstup do modulu
PSvolba režimu UART/PWM nebo I2C
SDAI2C data při režimu I2C
SCLI2C hodiny při režimu I2C

Podle dostupného manuálu má pin PS určovat režim modulu: pro UART/PWM má být v logické jedničce a pro I2C v logické nule. U mého konkrétního modulu se ale ukázalo, že PWM fungovalo spolehlivě při PS na VCC, zatímco UART komunikace se rozběhla až při PS na GND. Proto je dobré brát stav pinu PS jako věc, kterou je potřeba při oživování ověřit na konkrétním modulu.

Pro první pokusy je nejlepší nastavit PS natvrdo podle zvoleného režimu a nenechávat ho volně ve vzduchu.

Zapojení přes PWM

Začneme nejjednodušší variantou. Modul připojíme k Arduinu a budeme číst výstup PWM. Výhodou je, že není potřeba žádná knihovna. Arduino změří délku pulzu v mikrosekundách a podle jednoduchého vzorce vypočítá vzdálenost.

Zapojení může vypadat takto:

GY-53Arduino
VCC5V
GNDGND
PWMD7
PS5V
zapojení pro PWM čtení

Manuál uvádí, že PWM výstup má periodu 20 Hz a délka pulzu v logické jedničce odpovídá naměřené vzdálenosti. Vzdálenost v milimetrech se počítá jako délka pulzu v mikrosekundách dělená deseti. Například 10000 µs odpovídá vzdálenosti 1000 mm.

Ukázkový program pro PWM

const int pwmPin = 7;

void setup() {
Serial.begin(9600);
pinMode(pwmPin, INPUT);

Serial.println("GY-53 VL53L0X - mereni vzdalenosti pres PWM");
}

void loop() {
unsigned long delkaPulzu = pulseIn(pwmPin, HIGH, 60000);

if (delkaPulzu == 0) {
Serial.println("Bez signalu nebo mimo rozsah");
} else {
float vzdalenost_mm = delkaPulzu / 10.0;
float vzdalenost_cm = vzdalenost_mm / 10.0;

Serial.print("Delka pulzu: ");
Serial.print(delkaPulzu);
Serial.print(" us, vzdalenost: ");
Serial.print(vzdalenost_mm);
Serial.print(" mm / ");
Serial.print(vzdalenost_cm);
Serial.println(" cm");
}

delay(500);
}

Po nahrání programu otevřeme sériový monitor v Arduino IDE na rychlosti 9600 baud. Pokud je vše správně zapojené, měly by se zobrazovat naměřené vzdálenosti.

Funkce pulseIn() čeká na pulz a změří jeho délku. V tomto případě měříme délku logické jedničky na PWM výstupu. Získanou hodnotu vydělíme deseti a dostaneme vzdálenost v milimetrech.

Pro začátečníka je tohle asi nejjednodušší způsob, jak se senzorem začít. Není potřeba řešit datové rámce, kontrolní součty ani knihovny.

Zapojení přes UART

Druhá možnost je čtení hodnot přes sériovou linku UART. V tomto režimu modul neposílá PWM pulz, ale datové rámce, ve kterých je přímo naměřená vzdálenost.

Výhoda Arduina MEGA 2560 je v tom, že má více hardwarových sériových linek. Jedna sériová linka, označená jako Serial, je připojená k USB a používá se pro komunikaci s počítačem. Pro senzor proto použijeme další sériovou linku Serial1, která je na pinech:

Sériová linkaRXTX
Serial11918

Zapojení modulu GY-53 k Arduinu MEGA bude vypadat takto:

GY-53Arduino MEGA 2560
VCC5V
GNDGND
TXRX1 / pin 19
RXTX1 / pin 18
PSGND

Důležité je nezapomenout, že sériová linka se zapojuje křížem. Výstup TX z modulu jde na vstup RX1 Arduina.

zapojení pro UART čtení

Pro samotné čtení vzdálenosti by stačilo připojit jen TX modulu na RX1 Arduina, ale já jsem zapojil oba vodiče.

Tady je potřeba dát pozor na pin PS. Podle dostupného manuálu má být pro UART/PWM režim pin PS v logické jedničce, ale u mého konkrétního modulu se UART komunikace rozběhla až po připojení PS na GND. Při připojení PS na VCC fungovalo PWM měření, ale UART program stále vypisoval hlášení:

Nepodarilo se precist platny ramec

Po připojení PS na GND začal modul přes UART posílat platné datové rámce.

Proto bych doporučil při oživování vyzkoušet obě varianty pinu PS:

Režim testuPS
PWM měřeníVCC
UART měření u mého moduluGND

Výchozí rychlost sériové komunikace je opět 9600 baud.

Ukázkový program pro UART na Arduino MEGA

// GY-53 VL53L0X přes UART
// Arduino MEGA 2560
//
// Zapojení:
// GY-53 VCC -> 5V
// GY-53 GND -> GND
// GY-53 TX -> RX1 / pin 19
// GY-53 RX -> TX1 / pin 18
// GY-53 PS -> VCC

bool readByteWithTimeout(byte &value) {
unsigned long start = millis();

while (!Serial1.available()) {
if (millis() - start > 100) {
return false;
}
}

value = Serial1.read();
return true;
}

bool readGY53Frame(uint16_t &distance, byte &mode) {
byte b;

// Najdi začátek rámce 0x5A
do {
if (!readByteWithTimeout(b)) {
return false;
}
} while (b != 0x5A);

byte frame[8];
frame[0] = b;

// Druhý bajt musí být také 0x5A
if (!readByteWithTimeout(frame[1])) return false;
if (frame[1] != 0x5A) return false;

// Načti zbytek rámce
for (int i = 2; i < 8; i++) {
if (!readByteWithTimeout(frame[i])) {
return false;
}
}

// Kontrola typu rámce
if (frame[2] != 0x15 || frame[3] != 0x03) {
return false;
}

// Kontrolní součet
byte sum = 0;
for (int i = 0; i < 7; i++) {
sum += frame[i];
}

if (sum != frame[7]) {
return false;
}

// Vzdálenost je ve 4. a 5. datovém bajtu
distance = ((uint16_t)frame[4] << 8) | frame[5];

// Režim měření
mode = frame[6];

return true;
}

void setup() {
// Komunikace s PC přes USB
Serial.begin(9600);

// Komunikace se senzorem přes Serial1
Serial1.begin(9600);

Serial.println("GY-53 VL53L0X - mereni vzdalenosti pres UART");
Serial.println("Arduino MEGA 2560, senzor pripojeny na Serial1");
}

void loop() {
uint16_t distance;
byte mode;

if (readGY53Frame(distance, mode)) {
Serial.print("Vzdalenost: ");
Serial.print(distance);
Serial.print(" mm / ");
Serial.print(distance / 10.0);
Serial.print(" cm, rezim: ");
Serial.println(mode);
} else {
Serial.println("Nepodarilo se precist platny ramec");
}

delay(200);
}

Pro Arduino MEGA je tohle čistší řešení než SoftwareSerial. USB sériová linka zůstane volná pro výpis do sériového monitoru a senzor běží samostatně na Serial1. Tím odpadá spousta možných problémů s mnohdy nespolehlivým softwarovým sériovým portem.

Režimy měření

Modul GY-53 neumí jen jeden způsob měření. Přes UART lze nastavit několik režimů, které se liší hlavně rychlostí měření, dosahem a přesností. Podle manuálu modul podporuje obecné měření, přesné měření, rychlé měření a měření na delší vzdálenost. Výchozí režim je High precision, tedy přesné měření.

Přehled režimů:

RežimPříkazHodnota režimu ve výpisuDosahRychlost aktualizacePoznámka
Long distanceA5 50 F50x000–2 mcca 35 msvětší dosah, menší přesnost
FastA5 51 F60x010–1,2 mcca 22 msrychlé měření
High precisionA5 52 F70x020–1,2 mcca 200 mspřesné měření, výchozí režim
GeneralA5 53 F80x030–1,2 mcca 35 msběžný univerzální režim

Příkaz má vždy tři bajty. První bajt je 0xA5, druhý bajt určuje příkaz a třetí bajt je kontrolní součet. Například pro nastavení režimu Long distance se pošle:

A5 50 F5

Pro Fast režim:

A5 51 F6

Pro High precision režim:

A5 52 F7

A pro General režim:

A5 53 F8

Modul podle manuálu umí také uložit nastavení do paměti příkazem A5 25 CA. Bez uložení by se po vypnutí napájení mohlo nastavení vrátit zpět na původní hodnoty.

Pro první testy bych ale nastavení do paměti zatím neukládal. Je lepší si režimy jen vyzkoušet v programu a teprve až bude jasné, který režim se hodí nejvíc, ho uložit natrvalo nebo ho nastavit pokaždé při startu programu.

Nastavení režimu v programu

Protože na Arduinu MEGA používám pro komunikaci se senzorem hardwarovou sériovou linku Serial1, je poslání příkazu jednoduché. Stačí odeslat tři bajty.

Tady je jednoduchá funkce pro odeslání příkazu:

void posliPrikaz(byte b1, byte b2, byte b3) {
Serial1.write(b1);
Serial1.write(b2);
Serial1.write(b3);
}

A z ní si můžeme udělat přehlednější funkce pro jednotlivé režimy:

void nastavLongDistance() {
posliPrikaz(0xA5, 0x50, 0xF5);
}

void nastavFast() {
posliPrikaz(0xA5, 0x51, 0xF6);
}

void nastavHighPrecision() {
posliPrikaz(0xA5, 0x52, 0xF7);
}

void nastavGeneral() {
posliPrikaz(0xA5, 0x53, 0xF8);
}

void ulozNastaveni() {
posliPrikaz(0xA5, 0x25, 0xCA);
}

V programu pak stačí v části setup() zavolat režim, který chci použít. Například pro měření na delší vzdálenost:

void setup() {
Serial.begin(9600);
Serial1.begin(9600);

Serial.println("GY-53 VL53L0X - UART test rezimu mereni");

delay(500);

nastavLongDistance();

Serial.println("Nastaven rezim Long distance");
}

Pokud bych chtěl místo toho přesné měření, použil bych:

nastavHighPrecision();

Pro rychlé měření:

nastavFast();

A pro běžný univerzální režim:

nastavGeneral();

Ukázkový program s volbou režimu

Tady je upravená verze programu pro Arduino MEGA 2560. Režim měření se nastavuje hned po startu programu. Stačí odkomentovat ten režim, který chci vyzkoušet.

// GY-53 VL53L0X přes UART
// Arduino MEGA 2560
//
// Zapojení:
// GY-53 VCC -> 5V
// GY-53 GND -> GND
// GY-53 TX -> RX1 / pin 19
// GY-53 RX -> TX1 / pin 18
//
// U mého modulu fungoval UART při PS -> GND.
// Pokud komunikace nefunguje, vyplatí se vyzkoušet i PS -> VCC.

void posliPrikaz(byte b1, byte b2, byte b3) {
Serial1.write(b1);
Serial1.write(b2);
Serial1.write(b3);
}

void nastavLongDistance() {
posliPrikaz(0xA5, 0x50, 0xF5);
}

void nastavFast() {
posliPrikaz(0xA5, 0x51, 0xF6);
}

void nastavHighPrecision() {
posliPrikaz(0xA5, 0x52, 0xF7);
}

void nastavGeneral() {
posliPrikaz(0xA5, 0x53, 0xF8);
}

void ulozNastaveni() {
posliPrikaz(0xA5, 0x25, 0xCA);
}

bool readByteWithTimeout(byte &value) {
unsigned long start = millis();

while (!Serial1.available()) {
if (millis() - start > 100) {
return false;
}
}

value = Serial1.read();
return true;
}

bool readGY53Frame(uint16_t &distance, byte &mode) {
byte b;

// Najdi začátek rámce 0x5A
do {
if (!readByteWithTimeout(b)) {
return false;
}
} while (b != 0x5A);

byte frame[8];
frame[0] = b;

if (!readByteWithTimeout(frame[1])) return false;
if (frame[1] != 0x5A) return false;

for (int i = 2; i < 8; i++) {
if (!readByteWithTimeout(frame[i])) {
return false;
}
}

if (frame[2] != 0x15 || frame[3] != 0x03) {
return false;
}

byte sum = 0;
for (int i = 0; i < 7; i++) {
sum += frame[i];
}

if (sum != frame[7]) {
return false;
}

distance = ((uint16_t)frame[4] << 8) | frame[5];
mode = frame[6];

return true;
}

String nazevRezim(byte mode) {
switch (mode) {
case 0x00: return "Long distance";
case 0x01: return "Fast";
case 0x02: return "High precision";
case 0x03: return "General";
default: return "Neznamy";
}
}

void setup() {
Serial.begin(9600);
Serial1.begin(9600);

Serial.println("GY-53 VL53L0X - nastaveni rezimu mereni pres UART");

delay(500);

// Vyber jeden z rezimu:
nastavLongDistance();
//nastavFast();
//nastavHighPrecision();
//nastavGeneral();

// Pokud chci nastavení uložit trvale, odkomentuji:
//ulozNastaveni();

Serial.println("Rezim nastaven");
}

void loop() {
uint16_t distance;
byte mode;

if (readGY53Frame(distance, mode)) {
Serial.print("Vzdalenost: ");
Serial.print(distance);
Serial.print(" mm / ");
Serial.print(distance / 10.0);
Serial.print(" cm, rezim: ");
Serial.print(mode);
Serial.print(" - ");
Serial.println(nazevRezim(mode));
} else {
Serial.println("Nepodarilo se precist platny ramec");
}

delay(200);
}

Který režim použít

Pro běžné pokusy na stole bych začal režimem High precision. Je sice pomalejší, ale měl by dávat stabilnější výsledky.

Pokud bych chtěl měřit rychle se měnící vzdálenost, třeba u robota, zkusil bych režim Fast. Ten má rychlejší aktualizaci, ale je potřeba počítat s horší přesností.

Pro měření na větší vzdálenost bych použil Long distance. Tady se dostaneme až ke dvěma metrům, ale reálný výsledek bude víc záviset na povrchu, světle a velikosti měřeného objektu.

Režim General bych bral jako univerzální kompromis. Není tak pomalý jako High precision a zároveň není vyloženě zaměřený jen na rychlost.

I2C režim

Na modulu najdeme také vývody SDA a SCL. Může to svádět k tomu, že se modul prostě připojí jako běžné I2C čidlo a bude hotovo. U GY-53 je ale potřeba si dát pozor na režim pinu PS.

Podle dostupného manuálu by měl pin PS přepínat modul mezi UART/PWM režimem a I2C režimem. U mého kusu se ale chování pinu PS při UARTu lišilo od popisu, proto je dobré chování vždy ověřit.

I2C režim tedy může být zajímavý, pokud chceme použít běžnou knihovnu pro VL53L0X a mít nad čipem větší kontrolu. Pro jednoduché použití je ale podle mě jednodušší použít PWM nebo UART a proto jsem I2C režim ani netestoval.

Na co si dát pozor při zapojení

Modul je podle určený pro napájení 3–5 V. S Arduinem UNO nebo MEGA tedy můžeme použít 5 V. Pokud bych modul připojoval k ESP8266 nebo ESP32, raději bych ho napájel z 3,3 V nebo si ověřil logické úrovně konkrétní desky. U 3,3V mikrokontrolérů je obecně dobré dávat pozor na to, aby na jejich vstupy nešlo 5 V.

Důležité je také nezapomenout na společnou zem. Arduino i senzor musí mít propojený GND, jinak nebude měření ani komunikace fungovat správně.

U PWM měření může být výsledek občas nulový, pokud Arduino nestihne pulz zachytit nebo je senzor mimo rozsah. Proto je dobré hodnoty trochu filtrovat nebo průměrovat, pokud je budeme používat v reálném projektu.

Praktické testy

U podobných senzorů je nejlepší nevěřit jen tabulkovým hodnotám, ale vzít metr a vyzkoušet si chování v praxi. Právě u takových pokusů se nejlépe ukáže, co senzor zvládá a kde už začíná mít problém. U ToF senzorů může hrát roli velikost cíle, jeho úhel, povrch i okolní světlo. Výrobce čipu sice uvádí, že VL53L0X měří vzdálenost bez ohledu na odrazivost cíle v porovnání s běžnými technologiemi, v praktických amatérských podmínkách ale extrémní povrchy stále stojí za vyzkoušení.

Kde se dá senzor použít

GY-53 VL53L0X se hodí všude tam, kde potřebujeme měřit kratší vzdálenost bez mechanického kontaktu. Například:

  • malý robot a detekce překážek
  • měření vzdálenosti předmětu na stole
  • jednoduché měření výšky hladiny v nádobě
  • detekce přiblížení ruky
  • automatické spuštění zařízení při přiblížení objektu
  • školní a domácí pokusy s měřením vzdálenosti

Na dlouhé vzdálenosti nebo měření v řádu mnoha metrů to ale není. Tady je potřeba použít jiný typ senzoru nebo hotový laserový dálkoměr.

Shrnutí

Modul GY-53 VL53L0X je zajímavý dálkoměr pro Arduino a další mikrokontroléry. Měří vzdálenost pomocí infračerveného světla a metody Time-of-Flight. Oproti ultrazvukovému HC-SR04 je menší, nepoužívá zvuk a může být vhodnější pro některé přesnější pokusy na kratší vzdálenost.

Velká výhoda konkrétního modulu GY-53 je v tom, že má vlastní mikrokontrolér a umí posílat hotovou hodnotu vzdálenosti přes PWM nebo UART. Díky tomu se dá jednoduše použít i bez složité knihovny. Pro úplný začátek je podle mě nejlepší PWM výstup, protože stačí jeden datový vodič a jednoduchý výpočet z délky pulzu.

Jako vždy ale platí, že tabulka v datasheetu je jedna věc a reálné měření druhá. Proto se vyplatí vzít metr, vyzkoušet různé vzdálenosti, různé povrchy a podívat se, jak se senzor chová v praxi. Právě na takových jednoduchých pokusech se dá nejlépe pochopit, co od podobného modulu čekat.

Tento dálkoměr zakoupíte na Laskakit.cz přímý odkaz je ZDE.

Jedna myšlenka na “Měření vzdálenosti světlem: laserový dálkoměr GY-53 VL53L0X”

Napsat komentář

Vaše e-mailová adresa nebude zveřejněna. Vyžadované informace jsou označeny *